home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Mac100% 1999 April
/
MAC100-1999-04.ISO.7z
/
MAC100-1999-04.ISO
/
オンラインソフト定点観測
/
Network
/
Jnifty Auto b10.sit
/
Jnifty Auto b10
/
Login Script
< prev
next >
Wrap
Text File
|
1999-01-31
|
32KB
|
1,913 lines
************************
* Jnifty by Ko Tsuneta *
************************
****************
* Main Routine *
****************
***** Get Date *****
date:$date$:
set:#predate#:2$date$
sub:#predate#:1
strext:$str$:6:7:#predate#
if:04:$str$<>00
strext:$str$:4:7:#predate#
if:03:$str$==0100
strwhere:#num#:0[24689]00:$str$
if:02:#num#==1
if:02:$str$==1100
if:01:$str$<>0300
strext:$str$:1:4:#predate#
set:#num#:$str$
mod:#num#:4
if:00:#num#==0
sub:#predate#:72
j:04
00:
sub:#predate#:71
j:04
01:
sub:#predate#:70
j:04
02:
sub:#predate#:69
j:04
03:
sub:#predate#:8869
04:
strext:$predate$:2:8:#predate#
***** Maintenance? *****
date:$logdate$:/
time:$time$:/
week:#num#
if:10:#num#<>4
strext:$str$:5:6:$date$
set:#num#:$str$
if:10:#num#<<15
if:10:#num#>>21
strext:$str$:1:2:$time$
set:#num#:$str$
if:10:#num#<<01
if:10:#num#>>07
m:メンテナンス中です
j:981
***** Where? *****
10:
set:#go#:1
exist:11:SCRIPT:BBS.aps
sub:#go#:1
11:
firstfile:$fname$:POST:¥^BBS
if:12:$fname$==
add:#go#:2
12:
exist:13:SCRIPT:PATIOPR.aps
j:14
13:
add:#go#:4
14:
firstfile:$fname$:POST:¥^PATIOPR
if:15:$fname$==
add:#go#:8
15:
exist:16:SCRIPT:MES.aps
j:17
16:
add:#go#:16
17:
exist:18:SCRIPT:WSEA.aps
j:19
18:
add:#go#:32
19:
exist:20:SCRIPT:SEArch.aps
j:21
20:
add:#go#:64
21:
exist:22:SCRIPT:DownList.lib
j:23
22:
add:#go#:128
23:
firstfile:$fname$:POST:¥^[¥^_@]*[A-Z][0-9]?[0-9]?[0-9]?[0-9]?-
if:24:$fname$==
add:#go#:256
24:
exist:25:SCRIPT:PATIO.aps
j:70
25:
add:#go#:512
***** Setting *****
70:
exist:71:SCRIPT:SETTING.aps
m:SETTING.apsが見つかりません
j:981
71:
fopen:#setref#:SCRIPT:SETTING.aps
fread:#setref#:$line$
strwhere:#num#:/:$line$
if:73:#num#<>1
strext:$id$:2:9:$line$
strwhere:#num#:$id$:$i$
if:74:#num#==0
add:#num#:8
div:#num#:9
nthstr2: :$pw$:#num#:$p$
gosub:1003
if:73:$temset$<>DIAL
strmatch:$temset$:[0-9]+:$line$
set:#dial#:$temset$
if:73:#dial#>>9
set:$set$:
gosub:1003
if:73:$temset$<>DLM
gosub:1000
if:73:$temset$<>TERMINAL
gosub:1000
if:73:$temset$<>TEXTMAIL
nthstr:$mailset$:2:$line$
gosub:1003
if:73:$temset$<>BINARYMAIL
gosub:1000
if:73:$temset$<>DELETEMAIL
gosub:1000
if:73:$temset$<>SENDMAIL
gosub:1000
if:73:$temset$<>FORUMOPT
gosub:1000
if:73:$temset$<>MES
gosub:1000
if:73:$temset$<>LIB
gosub:1000
if:73:$temset$<>COMMENT
gosub:1000
if:73:$temset$<>BILL
nthstr:$temset$:2:$line$
nthstr2:¥r:$temset$:1:$temset$
set:$set$:$set$-$temset$
gosub:1003
if:73:$temset$<>LOGALL
gosub:1000
if:73:$temset$<>LOGTIME
gosub:1000
if:73:$temset$<>LOGCUT
gosub:1000
if:73:$temset$<>QUIT
nthstr:$temset$:2:$line$
if:72:$temset$==ON^m
set:$set$:$set$-0
j:80
72:
set:$set$:$set$-1
j:80
73:
m:SETTING.apsのフォーマットが正しくありません
j:980
74:
m:SETTING.apsにあるIDが見つかりません
j:980
***** Login *****
80:
exist:81:POST:__visited__forums__list__
create:JEDT:TEXT:POST:__visited__forums__list__
81:
fopen:#vflref#:POST:__visited__forums__list__
fwrite:#vflref#:^m
set:$mainset$:$set$
set:#times#:0
if:90:#dial#==9
dial:90:#dial#
m:回線が混雑しているようです
j:980
90:
if:98:#times#>>2
t:91:5:Connection-ID|92:*|93:Login
s:^h^h
j:95
91:
gosub:1090
strwhere:#num#:¥¥::$line$
if:93:#num#<>0
add:#times#:1
s:@P^m
t:94:5:*
92:
s:C NIF
j:94
93:
s:NIFTY^m
r:Password|95:Connection-ID
94:
s:^m
t:96:5:Connection-ID|97:User-ID|98:Clear|99:Password|92:*|93:Login
95:
s:SVC
j:94
96:
if:90:#dial#<>9
closeport:
openport:
d:7
j:90
97:
s:$id$
j:94
98:
m:何らかの理由で接続できなかったようです
j:980
99:
clock:reset
clock:on
line:#logstart#
add:#logstart#:2
s:$pw$^m
ftype:m
set:#sendmexp#:0
set:$mailstate$:0
set:$waitt$:^j題名 (漢字で20文字まで)^m
set:$waitr$::0−^m^j−この会議室はリードオンリーです−^m^jCCS(
r:^j只今の時間|100:す(未読分|120:^j>
j:980
***** Recive Mail *****
100:
gosub:1090
if:100:$line$<>>
gosub:1010
if:101:$mailset$==ON^m
if:110:$mailset$<>NEW^m
101:
gosub:1020
s:REAd NEW^m
nthstr:$temset$:5:$set$
102:
r:action:|110:^jMAIL>
gosub:1090
if:102:$line$<>action:
if:103:$temset$==0
s:*^hDELete^m
j:102
103:
s:*^hSAVe^m
j:102
110:
nthstr:$temset$:4:$set$
if:130:$temset$==0
if:111:$temset$==$mailstate$
gosub:1020
111:
line:#start#
s:LISt^m
add:#start#:2
r:^jMAIL>
line:#end#
sub:#end#:1
if:112:$mailstate$==1
sub:#end#:1
112:
while:#end#>>#start#
getline:$line$:#end#
set:$line$:$line$^m
strwhere:#num#:¥^ +[0-9]+ +.+[01][0-9]/[0-3][0-9] [ F]B :$line$
if:113:$mailstate$<>2
strwhere:#num#:B [-F] - - [0-9A-Z]+¥¥r:$line$
113:
if:115:#num#==0
strmatch:$str$:[0-9A-Z]+¥¥r:$line$
s:DOWn PROT:BPL $str$
r:^j:
s:$str$
r:開始−^m^j
d:2
dlBplus:
r:^j:
nthstr:$temset$:5:$set$
if:114:$temset$==0
s:1^m
r:^jMAIL>
j:115
114:
s:2^m
r:^jMAIL>
115:
sub:#end#:1
if:116:$mailstate$==1
sub:#end#:1
116:
wend:
j:130
***** Read Announce *****
120:
gosub:1091
strwhere:#num#:トップメニュー):$line$
gosub:1010
if:130:#num#==0
firstfile:$fname$:POST:¥^NEW
if:130:$fname$==
121:
strext:$line$:4:31:$fname$
s:$line$
rename:POST:$fname$:_NEW
if:123:#err#==0
set:#usnum#:0
122:
add:#usnum#:1
rename:POST:$fname$:_#usnum#_NEW
if:122:#err#<>0
123:
s:^m
r:終了^m^j>|123:終了)^m^j>|130:^j>
***** Send Mail *****
130:
nthstr:$temset$:6:$set$
if:160:$temset$==0
131:
firstfile:$fname$:POST:¥^MAIL
if:160:$fname$==
fopen:#mesref#:POST:$fname$
fread:#mesref#:$mesline$
if:132:$mesline$<>#!MEXP^m
fread:#mesref#:$mesline$
if:132:#sendmexp#==2
set:#sendmexp#:1
132:
strwhere:#num#:#!FN:$mesline$
if:140:#num#==1
strwhere:#num#:TO:$mesline$
if:133:#num#==1
fclose:#mesref#
set:$us$:_?
gosub:2700
j:131
133:
gosub:1300
j:131
140:
strext:$upfname$:5:99:$mesline$
strwhere:#num#:B¥¥::$upfname$
if:141:#num#<>1
strext:$upfname$:3:99:$upfname$
ftype:b
141:
nthstr2:¥r:$upfname$:1:$upfname$
exist:142:$upfname$
fclose:#mesref#
set:$us$:_?
gosub:2700
j:131
142:
set:$title$:untitled^m
fread:#mesref#:$mesline$
strwhere:#num#:#!TT:$mesline$
if:144:#num#<>1
strlen:#length#:$mesline$
if:143:#length#<<6
strext:$title$:5:99:$mesline$
143:
fread:#mesref#:$mesline$
144:
strwhere:#num#:TO:$mesline$
if:150:#num#==1
fclose:#mesref#
set:$us$:_?
gosub:2700
j:131
150:
gosub:1300
if:131:$mailto$==$id$
s:UPLoad TYPE:BIN PROT:BPL^m
gosub:2100
t:151:10::
line:#num#
sub:#num#:3
getline:$line$:#num#
strwhere:#num#:−アップロード終了−:$line$
if:152:#num#==1
m:^m:^m:
j:152
151:
m:−アップロード終了−^mバイト受信しました^m題名 (漢字で20文字まで)^m:
152:
s:$title$
r:^j:
s:1^m
r:^j:
set:#times#:1
153:
nthstr2:,:$sendid$:#times#:$mailto$
add:#times#:1
strwhere:#num#:¥¥r:$sendid$
nthstr2:¥r:$sendid$:1:$sendid$
s:$sendid$^m
r:◆^m^j|155:^j:
154:
if:153:#num#==0
s:^m
r:^j:
155:
s:1^m
r:期日指定)^m^j:|131:^jMAIL>|154:^j:
j:155
***** Read Announce? *****
160:
firstfile:$fname$:POST:¥^NEW
if:170:$fname$==
s:GO NEW^m
r:^j>
j:121
***** Mail to Center *****
170:
firstfile:$fname$:POST:¥^CENTER-1-
if:180:$fname$==
s:GO SUPPORT^m
r:^j>
s:4^m
r:^j>
171:
s:1^m
r:^j>
s:1^m
fopen:#mesref#:POST:$fname$
r:行頭で/E)^m^j
gosub:2000
r:$waitt$|172:^j>
gosub:1080
r:^j>
172:
firstfile:$fname$:POST:¥^CENTER-1-
if:171:$fname$<>
***** POSPE MACRO *****
180:
isexternal:#num#
if:200:#num#==2
if:190:$mailset$<>PET^m
exist:181:SCRIPT:ExPet.aps
j:190
181:
external:ExPet.aps
***** External Script *****
190:
firstfile:$fname$:SCRIPT:¥^Ex[¥^:]*.aps
191:
if:200:$fname$==
if:192:$fname$==ExPet.aps
strwhere:#num#:.aps[¥^¥¥:]:$fname$
if:192:#num#<>0
external:$fname$
192:
nextfile:$fname$
j:191
***** BBS *****
200:
if:900:#go#<<1
exist:201:SCRIPT:BBS.aps
j:210
201:
fopen:#refnum#:SCRIPT:BBS.aps
202:
fread:#refnum#:$bbsline$
if:205:#err#<>0
if:205:$bbsline$==/END^m
gosub:1030
if:202:$bbsline$==FAIL
s:SCAn DATE:
nthstr:$bbs$:2:$bbsline$
if:203:$bbs$<>Y
s:$predate$
j:204
203:
s:$date$
204:
s:^m
r:^j>|204:^j:|202:^jBBS>
nthstr:$bbs$:3:$bbsline$
if:202:$bbs$<>R
gosub:1040
j:202
205:
fclose:#refnum#
210:
if:900:#go#<<2
211:
firstfile:$fname$:POST:¥^BBS[0-9]
if:220:$fname$==
fopen:#refnum#:POST:$fname$
fread:#refnum#:$bbsline$
gosub:1030
if:214:$bbsline$==FAIL
fread:#refnum#:$bbsline$
fclose:#refnum#
set:$us$:_
gosub:2700
strmatch:$bbsid$:[A-Z][A-Z][A-Z][0-9][0-9][0-9][0-9][0-9]:$bbsline$
strext:$year$:1:2:$date$
strmatch:$day$:[ 1][0-9]/[0-3][0-9]:$bbsline$
strmatch:$month$:[0-9]+:$day$
strlen:#num#:$month$
if:212:#num#>>1
set:$month$:0$month$
212:
strext:$day$:4:5:$day$
s:SCAn DATE:$year$$month$$day$^m
r:^j:|211:^jBBS>
s:$bbsid$
213:
s:^m
r:^j>|213:^j:|211:^jBBS>
gosub:1040
j:211
214:
fclose:#refnum#
set:$us$:_?
gosub:2700
j:211
220:
if:900:#go#<<4
exist:221:SCRIPT:PATIOPR.aps
j:230
221:
fopen:#refnum#:SCRIPT:PATIOPR.aps
222:
fread:#refnum#:$bbsline$
if:225:#err#<>0
if:225:$bbsline$==/END^m
strmatch:$bbs$:¥^[2-7]:$bbsline$
if:222:$bbs$==
s:GO PATIOPR^m
r:^j>
s:$bbs$^m
r:^jBBS>
s:SCAn DATE:
nthstr:$bbs$:2:$bbsline$
if:223:$bbs$<>Y
s:$predate$
j:224
223:
s:$date$
224:
s:^m
r:^j>|224:^j:|222:^jBBS>
nthstr:$bbs$:3:$bbsline$
if:222:$bbs$<>R
gosub:1040
j:222
225:
fclose:#refnum#
230:
if:900:#go#<<8
231:
firstfile:$fname$:POST:¥^PATIOPR[0-9]
if:300:$fname$==
fopen:#refnum#:POST:$fname$
fread:#refnum#:$bbsline$
strmatch:$bbs$:¥^[2-7]:$bbsline$
if:234:$bbs$==
s:GO PATIOPR^m
r:^j>
s:$bbs$^m
r:^jBBS>
fread:#refnum#:$bbsline$
fclose:#refnum#
set:$us$:_
gosub:2700
strmatch:$bbsid$:[A-Z][A-Z][A-Z][0-9][0-9][0-9][0-9][0-9]:$bbsline$
strext:$year$:1:2:$date$
strmatch:$day$:[ 1][0-9]/[0-3][0-9]:$bbsline$
strmatch:$month$:[0-9]+:$day$
strlen:#num#:$month$
if:232:#num#>>1
set:$month$:0$month$
232:
strext:$day$:4:5:$day$
s:SCAn DATE:$year$$month$$day$^m
r:^j:|231:^jBBS>
s:$bbsid$
233:
s:^m
r:^j>|233:^j:|231:^jBBS>
gosub:1040
j:231
234:
fclose:#refnum#
set:$us$:_?
gosub:2700
j:231
***** Forum *****
300:
if:900:#go#<<16
exist:301:SCRIPT:MES.aps
j:330
301:
fopen:#refnum#:SCRIPT:MES.aps
302:
fread:#refnum#:$roomline$
if:322:#err#<>0
if:322:$roomline$==/END^m
nthstr2:¥r:$forum$:1:$roomline$
fread:#refnum#:$roomline$
nthstr2:¥r:$roomline$:1:$roomline$
gosub:1060
if:302:$forum$==FAIL
exist:303:SCRIPT:WSEA.aps
j:306
303:
fopen:#wsearef#:SCRIPT:WSEA.aps
304:
fread:#wsearef#:$wsealine$
if:305:#err#<>0
if:304:$wsealine$<>¥¥m$forum$^m
gosub:2400
305:
fclose:#wsearef#
306:
gosub:1100
nthstr2:/:$room$:1:$roomline$
if:320:$room$==
if:313:#roomon#==2
strmatch:$temroom$:[0-9]+:$room$
if:310:$temroom$<>
set:$temroom$:1
310:
nthstr:$temset$:8:$set$
if:311:$temset$==0
if:311:#roomon#==1
s:MES^m
r:^j>|321:^jFORUM>
311:
s:MES $temroom$^m
set:#roomon#:2
strwhere:#num#:[Aa,-]:$room$
r:$waitr$|312::0−^m^jCCS(|313:^j>|321:^jFORUM>|313:^jCCS(
312:
if:320:#num#==0
313:
s:MREad ROOM:$room$^m
314:
r:^h^m^jCCS(|320:^h^m^j>|315:^jCCS(|315:^j>
j:320
315:
silence:60
s2:
silence:9
gosub:1090
if:320:$line$==CCS(N)>
if:320:$line$==CCS(P)>
if:314:$line$<>>
320:
gosub:1110
set:#num#:2
set:$title$:RMN
gosub:2600
set:#num#:3
set:$title$:RTN
gosub:2600
321:
gosub:1120
gosub:1130
gosub:1140
j:302
322:
fclose:#refnum#
330:
if:900:#go#<<32
exist:331:SCRIPT:WSEA.aps
j:340
331:
fopen:#wsearef#:SCRIPT:WSEA.aps
332:
fread:#wsearef#:$wsealine$
if:333:#err#<>0
if:333:$wsealine$==/END^m
set:$line$:$wsealine$
gosub:1050
if:332:$forum$==FAIL
gosub:2400
gosub:1100
gosub:1110
gosub:1120
gosub:1130
gosub:1140
j:332
333:
fclose:#wsearef#
set:$fname$:WSEA.aps
gosub:2710
340:
if:900:#go#<<64
exist:341:SCRIPT:SEArch.aps
j:350
341:
fopen:#searef#:SCRIPT:SEArch.aps
342:
fread:#searef#:$sealine$
if:343:#err#<>0
if:343:$sealine$==/END^m
set:$line$:$sealine$
gosub:1050
if:342:$forum$==FAIL
gosub:2200
gosub:1130
gosub:1140
gosub:1100
gosub:1110
j:342
343:
fclose:#searef#
set:$fname$:SEArch.aps
gosub:2710
350:
if:900:#go#<<128
exist:351:SCRIPT:DownList.lib
j:360
351:
fopen:#downref#:SCRIPT:DownList.lib
352:
fread:#downref#:$downline$
if:354:#err#<>0
353:
set:$line$:$downline$
gosub:1050
if:352:$forum$==FAIL
gosub:2300
gosub:1140
gosub:1100
gosub:1110
if:353:$down$<>END
354:
fclose:#downref#
set:$fname$:DownList.lib
gosub:2710
360:
if:900:#go#<<256
361:
firstfile:$fname$:POST:¥^[¥^_@]*[A-Z][0-9]?[0-9]?[0-9]?[0-9]?-
if:400:$fname$==
nthstr:$temforum$:1:$fname$
nthstr:$room$:2:$fname$
if:364:$temforum$==$forum$
set:$forum$:$temforum$
gosub:1060
if:364:$forum$<>FAIL
362:
set:$us$:_?
gosub:2700
firstfile:$fname$:POST:¥^[¥^_@]*[A-Z][0-9]?[0-9]?[0-9]?[0-9]?-
363:
if:361:$fname$==
nthstr:$temforum$:1:$fname$
if:362:$temforum$==$forum$
nextfile:$fname$
j:363
364:
strwhere:#num#:LIB:$room$
if:367:#num#==1
strmatch:$str$:[0-9]+:$room$
set:#num#:$str$
if:365:#num#>>20
gosub:1400
j:361
365:
set:$readf$:$fname$
strext:$str$:1:1:$room$
strext:$room$:2:2:$room$
if:366:$str$==4
set:$room$:1$room$
if:366:$str$==5
set:$room$:20
366:
gosub:2500
j:361
367:
strext:$uplib$:4:5:$room$
gosub:1500
j:361
***** Patio *****
400:
if:900:#go#<<512
fopen:#patioref#:SCRIPT:PATIO.aps
401:
fread:#patioref#:$line$
if:499:#err#<>0
if:499:$line$==/END^m
if:401:$line$<>/$id$^m
set:#roomon#:0
set:$title$:
410:
fread:#patioref#:$line$
if:499:#err#<>0
if:499:$line$==/END^m
strwhere:#num#:/[A-Z][A-Z][A-Z][0-9][0-9][0-9][0-9][0-9]¥¥r:$line$
if:499:#num#==1
strmatch:$patioi$:¥^[A-Z][A-Z][A-Z][0-9][0-9][0-9][0-9][0-9]:$line$
if:411:$patioi$<>
strwhere:#num#:/R[MT]N¥¥r:$line$
if:410:#num#<>1
strext:$title$:2:5:$line$
j:410
411:
nthstr2: :$patiop$:2:$line$
nthstr2: :$patios$:3:$line$
if:412:#roomon#==1
if:413:#roomon#==2
s:DO PATIO/
set:#roomon#:1
412:
s:2^m
j:414
413:
s:MOVe^m
414:
r:^j:
s:$patioi$^m
gosub:1230
r:ワード^m^j:|410:−^m^j|415:^j:|416:^j>
s:$patiop$^m
r:^j:|416:^j>
415:
s:2^m
r:^j>|410:^jPATIO(|415:^j:
j:410
416:
set:#roomon#:2
gosub:1091
strwhere:#mesnum#: 1 +[0-9]+ ( 0) [01][0-9]/[0-3][0-9] :$line$
strwhere:#num#:/GUEst:$patios$
if:417:#num#==0
s:GUEst^m
r:^j>
s:^m
r:^j>
417:
if:430:$title$<>
if:420:#mesnum#==0
if:410:$fname$==
420:
gosub:1070
gosub:1600
line:#read#
add:#read#:2
s:MREad^m
421:
r:^h^m^jPATIO(|422:^jPATIO(
j:410
422:
line:#num#
if:410:#num#==#read#
nthstr:$temset$:2:$set$
if:421:$temset$==1
gosub:1090
if:410:$line$==PATIO(N)>
if:410:$line$<>PATIO(P)>
j:421
430:
gosub:1240
if:436:$readf$==
set:$patios$:
gosub:1070
431:
if:435:$readf$==
nthstr:$mes$:3:$readf$
line:#read#
add:#read#:2
s:#!$mes$^m
set:$us$:_
gosub:2720
gosub:1240
432:
r:^h^m^jPATIO(|433:^jPATIO(
j:431
433:
line:#num#
if:434:#num#<>#read#
gosub:2730
j:431
434:
nthstr:$temset$:2:$set$
if:432:$temset$==1
gosub:1090
if:431:$line$==PATIO(N)>
if:431:$line$==PATIO(P)>
j:432
435:
if:438:#mesnum#==0
if:410:$fname$==
j:438
436:
if:437:#mesnum#==0
if:410:$fname$==
437:
gosub:1070
438:
gosub:1600
gosub:1091
strwhere:#num#:>1:$line$
if:439:#num#==1
s:E^m
r:^j>
gosub:1070
439:
s:$title$
r:^j>
s:RC ALL^m
r:^jPATIO(
j:410
499:
fclose:#patioref#
***** Logout *****
900:
fclose:#vflref#
delete:POST:__visited__forums__list__
strext:$str$:6:6:$date$
nthstr:$temset$:11:$set$
strwhere:#num#:$str$:$temset$
if:901:#num#==0
s:GO BILL^m
r:^j>
s:2^m
r:^j>
901:
strwhere:#num#:[¥^0-9-]:$set$
if:902:#num#==0
g:
q:
902:
fread:#setref#:$line$
if:910:#err#<>0
if:910:$line$==/END^m
strwhere:#num#:/:$line$
if:902:#num#<>1
strext:$id$:2:9:$line$
strwhere:#num#:$id$:$i$
if:902:#num#==0
add:#num#:8
div:#num#:9
nthstr2: :$pw$:#num#:$p$
set:$set$:
gosub:1003
if:902:$temset$<>DLM
gosub:1000
if:902:$temset$<>TERMINAL
gosub:1000
if:902:$temset$<>TEXTMAIL
nthstr:$mailset$:2:$line$
gosub:1003
if:902:$temset$<>BINARYMAIL
gosub:1000
if:902:$temset$<>DELETEMAIL
gosub:1000
if:902:$temset$<>SENDMAIL
gosub:1000
set:$set$:$set$---
if:902:$temset$<>COMMENT
gosub:1000
if:902:$temset$<>BILL
s:LOG
nthstr:$temset$:2:$line$
nthstr2:¥r:$temset$:1:$temset$
set:$set$:$set$-$temset$
nthstr:$temset$:12:$mainset$
set:$set$:$set$-$temset$
nthstr:$temset$:13:$mainset$
set:$set$:$set$-$temset$
nthstr:$temset$:14:$mainset$
set:$set$:$set$-$temset$
nthstr:$temset$:15:$mainset$
set:$set$:$set$-$temset$
set:#go#:0
exist:903:SCRIPT:PATIO.aps
j:94
903:
add:#go#:256
j:94
910:
set:$set$:$mainset$
line:#logend#
s:OFF^m
add:#logend#:6
clock:off
t:911:5:*
j:912
911:
gosub:1090
strwhere:#num#:¥¥::$line$
if:920:#num#==0
912:
s:OFF^m
920:
fclose:#setref#
nthstr:$temset$:12:$set$
if:921:$temset$==0
set:#logstart#:1
add:#logend#:99
921:
set:$fname$:Jnifty log
append:#logstart#:#logend#:$fname$
nthstr:$temset$:14:$set$
if:923:$temset$==0
exec:Ccut:LOG:$fname$
set:$fname$:_$fname$
922:
d:10
exist:923:LOG:$fname$
j:922
923:
nthstr:$temset$:13:$set$
if:925:$temset$==1
rename:LOG:$fname$:$fname$.$logdate$
if:930:#err#==0
set:#usnum#:2
924:
rename:LOG:$fname$:$fname$.$logdate$*#usnum#
if:930:#err#==0
add:#usnum#:1
j:924
925:
rename:LOG:$fname$:$fname$.$logdate$.$time$
930:
firstfile:$fname$:POST:¥^[¥^_@]
if:931:$fname$==
set:$us$:_?
gosub:2700
j:930
931:
firstfile:$fname$:SCRIPT:¥^起動[¥^:]*.aps
932:
if:990:$fname$==
strwhere:#num#:.aps[¥^¥¥:]:$fname$
if:933:#num#<>0
launch:SCRIPT:$fname$
933:
nextfile:$fname$
j:932
980:
offline:
fclose:#setref#
981:
set:$set$:
append:1:999:Jnifty error log
990:
nthstr:$temset$:15:$set$
if:999:$temset$==1
close:
999:
exit:
***************
* Sub Routine *
***************
***** Option *****
*** Setting Option ***
1000:
set:#num#:0
nthstr:$temset$:2:$line$
if:1001:$temset$==ON^m
if:1002:$temset$<>NEW^m
add:#num#:1
1001:
add:#num#:1
1002:
set:$set$:$set$-#num#
1003:
fread:#setref#:$line$
nthstr:$temset$:1:$line$
ret:
*** Send SET ***
1010:
silence:9
recvBS:0
nthstr:$temset$:2:$set$
if:1011:$temset$==0
recvBS:2
s:SET DLM ON^m
r:^j>
1011:
nthstr:$temset$:3:$set$
if:1019:$temset$==0
s:SET MENu OFF^m
r:^j>
s:SET PAGe OFF^m
r:^j>
1019:
ret:
*** Enter Mail ***
1020:
set:$mailstate$:1
if:1021:$temset$==1
set:$mailstate$:2
s:GO NEW
1021:
s:MAIL^m
r:^jMAIL>
ret:
*** Enter BBS ***
1030:
strmatch:$bbs$:¥^[2-578][-¥r0][¥^/0-9]:$bbsline$
set:$bbs$:0$bbs$
if:1034:$bbs$<>0
strmatch:$bbs$:¥^1[014][-¥r0][¥^/0-9]:$bbsline$
if:1034:$bbs$<>
strmatch:$bbs$:¥^6[01][0-9][-¥r]:$bbsline$
if:1033:$bbs$<>
strmatch:$bbs$:¥^9[12][-¥r]:$bbsline$
set:$bbs$:0$bbs$
if:1032:$bbs$<>0
strmatch:$bbs$:¥^121[-¥r]:$bbsline$
if:1032:$bbs$<>
strmatch:$bbs$:¥^13[1-3][-¥r]:$bbsline$
if:1032:$bbs$<>
strmatch:$bbs$:¥^6/[1-9][-¥r]:$bbsline$
if:1031:$bbs$<>
strmatch:$bbs$:¥^6/1[0-7][-¥r]:$bbsline$
if:1031:$bbs$<>
strmatch:$bbs$:¥^9/[12][-¥r]:$bbsline$
if:1031:$bbs$<>
strmatch:$bbs$:¥^12/1[-¥r]:$bbsline$
if:1031:$bbs$<>
strmatch:$bbs$:¥^13/[1-3][-¥r]:$bbsline$
if:1036:$bbs$==
1031:
nthstr:$bbs$:1:$bbs$
nthstr2:¥r:$bbs$:1:$bbs$
j:1035
1032:
strext:$str$:1:2:$bbs$
set:#num#:$str$
strext:$str$:3:3:$bbs$
set:$bbs$:#num#/$str$
j:1035
1033:
strext:$str$:2:3:$bbs$
set:#num#:$str$
if:1036:#num#<<1
if:1036:#num#>>17
set:$bbs$:6/#num#
j:1035
1034:
strext:$str$:1:2:$bbs$
set:#num#:$str$
set:$bbs$:#num#
1035:
s:DO BBS/$bbs$^m
t:1036:20:◆^m|1036:18歳未満の方は|1036:生年月日を登録後|1039:^jBBS>
1036:
set:$bbsline$:FAIL
1039:
ret:
*** Read BBS ***
1040:
s:ALL^m
1041:
r:next>|1042:>
gosub:1090
if:1041:$line$<>next>
s:^m
j:1041
1042:
gosub:1090
if:1041:$line$<>>
ret:
*** Ready to Enter Forum ***
1050:
strwhere:#num#:¥¥¥¥m:$line$
if:1052:#num#<>1
strext:$forum$:3:99:$line$
fseek:#vflref#:0
1051:
fread:#vflref#:$vflline$
if:1052:$vflline$==$forum$
if:1051:#err#==0
nthstr2:¥r:$forum$:1:$forum$
gosub:1060
j:1059
1052:
set:$forum$:FAIL
1059:
ret:
*** Enter Forum ***
1060:
s:GO $forum$^m
fwrite:#vflref#:$forum$^m
set:#roomon#:0
set:#libon#:0
1061:
r:^j>|1066:下さい◆^m|1065:^jFORUM>|1062:^jmore>
gosub:1090
if:1061:$line$<>>
nthstr:$temset$:7:$set$
if:1066:$temset$==0
1062:
s:SET MENu OFF
1063:
s:^m
r:^jFORUM>|1063:^jmore>|1066:^j>
1064:
s:SET PAGe OFF^m
r:^jFORUM>
s:SET PAUSE OFF^m
r:^jFORUM>
1065:
s:SEND OFF^m
r:^jFORUM>
j:1069
1066:
set:$forum$:FAIL
1069:
ret:
*** Enter Patio Room ***
1070:
s:1^m
strwhere:#num#:/PAUSE:$patios$
if:1071:#num#<>0
r:^jPATIO(
s:SET PAUSE OFF^m
1071:
r:^jPATIO(
ret:
*** Send Untitled ***
1080:
s:Untitled^m
r:^j:
s:1^m
ret:
*** Get Line ***
1090:
line:#num#
j:1092
1091:
line:#num#
sub:#num#:1
1092:
getline:$line$:#num#
ret:
*** Send Message ***
1100:
gosub:1200
if:1109:$fname$==
gosub:1400
j:1100
1109:
ret:
*** Read Message ***
1110:
set:$temroom$:
firstfile:$readf$:POST:¥^[¥^_@]*[A-Z][0-9]?[0-9]?[0-9]?[0-9]?-[4-6][0-9]-
gosub:1220
set:$room$:$temroom$
if:1119:$readf$==
gosub:2500
j:1110
1119:
ret:
*** Search ***
1120:
exist:1121:SCRIPT:SEArch.aps
j:1129
1121:
set:#roomon#:0
fopen:#searef#:SCRIPT:SEArch.aps
1122:
fread:#searef#:$sealine$
if:1123:#err#<>0
if:1123:$sealine$==/END^m
if:1122:$sealine$<>¥¥m$forum$^m
gosub:2200
1123:
fclose:#searef#
1129:
ret:
*** Download ***
1130:
exist:1131:SCRIPT:DownList.lib
j:1139
1131:
fopen:#downref#:SCRIPT:DownList.lib
1132:
fread:#downref#:$downline$
if:1133:#err#<>0
if:1132:$downline$<>¥¥m$forum$^m
gosub:2300
1133:
fclose:#downref#:
1139:
ret:
*** Upload ***
1140:
gosub:1250
if:1149:$fname$==
gosub:1500
j:1140
1149:
ret:
***** Ready to Send or Read Message *****
*** Forum & Send ***
1200:
set:$temroom$:
firstfile:$fname$:POST:¥^[¥^_@]*[A-Z][0-9]?[0-9]?[0-9]?[0-9]?-[0-9]
1201:
if:1209:$fname$==
nthstr:$temforum$:1:$fname$
if:1202:$temforum$<>$forum$
nthstr:$temroom$:2:$fname$
strmatch:$str$:[0-9]+:$temroom$
set:#num#:$str$
if:1209:#num#<<21
1202:
nextfile:$fname$
j:1201
1209:
ret:
*** Forum & Same Room & Read ***
1210:
firstfile:$readf$:POST:¥^[¥^_@]*[A-Z][0-9]?[0-9]?[0-9]?[0-9]?-[4-6][0-9]-
1211:
gosub:1220
if:1219:$readf$==
if:1219:$room$==$temroom$
nextfile:$readf$
j:1211
1219:
ret:
*** Forum & Read & Sub ***
1220:
if:1229:$readf$==
nthstr:$temforum$:1:$readf$
if:1221:$temforum$==$forum$
nextfile:$readf$
j:1220
1221:
nthstr:$temroom$:2:$readf$
strext:$str$:1:1:$temroom$
strext:$temroom$:2:2:$temroom$
if:1229:$str$==4
set:$temroom$:1$temroom$
if:1229:$str$==5
set:$temroom$:20
1229:
ret:
*** Patio & Send ***
1230:
firstfile:$fname$:POST:¥^[A-Z][A-Z][A-Z][0-9][0-9][0-9][0-9][0-9]-1-
1231:
if:1232:$fname$==
nthstr:$patio$:1:$fname$
if:1232:$patioi$==$patio$
nextfile:$fname$
j:1231
1232:
ret:
*** Patio & Read ***
1240:
firstfile:$readf$:POST:¥^PT_[A-Z][A-Z][A-Z][0-9][0-9][0-9][0-9][0-9]-[49][19]-
1241:
if:1249:$readf$==
strext:$patio$:4:11:$readf$
if:1249:$patioi$==$patio$
nextfile:$readf$
j:1241
1249:
ret:
*** Library ***
1250:
firstfile:$fname$:POST:¥^[¥^_@]+-LIB[0-9]
1251:
if:1259:$fname$==
nthstr:$temforum$:1:$fname$
if:1252:$temforum$==$forum$
nextfile:$fname$
j:1251
1252:
nthstr:$uplib$:2:$fname$
strext:$uplib$:4:5:$uplib$
1259:
ret:
***** Send Text Mail *****
1300:
if:1301:$temset$==$mailstate$
gosub:1020
1301:
if:1310:#sendmexp#<>1
s:MEXP^m
set:#sendmexp#:2
r:^jMAIL>
1310:
s:COMpose^m
strext:$mailto$:4:999:$mesline$
r:行頭で/E)^m^j|1311:300行迄です)^m^j
1311:
s:$mesline$
strwhere:#num#:,¥¥r:$mailto$
if:1312:#num#==0
nthstr2:¥r:$mailto$:1:$mailto$
fread:#mesref#:$mesline$
set:$mailto$:$mailto$$mesline$
j:1311
1312:
gosub:2000
r:$waitt$|1313:終了)^m^j|1399:^jMAIL>
gosub:1080
r:^j:|1399:^jMAIL>
1313:
d:2
set:$mailto$:$id$
s:$id$^m
r:^j:
s:1^m
r:^j:
s:^m
r:^jMAIL>
1399:
ret:
***** Send Message in Forum *****
1400:
nthstr:$room$:2:$fname$
if:1402:#roomon#==2
nthstr:$temset$:8:$set$
if:1401:$temset$==0
if:1401:#roomon#==1
s:MES^m
r:^j>
1401:
s:MES $room$^m
r:^jCCS(|1403:^j>|1403:^jFORUM>
j:1410
1402:
s:RX $room$^m
r:せん◆^m^j|1410:−^m^jCCS(
1403:
set:$us$:_?
gosub:2700
gosub:1200
if:1403:$temroom$==$room$
j:1499
1410:
set:#roomon#:2
gosub:1700
gosub:1200
if:1411:#fail#==1
r:$waitt$|1411:^jCCS(
gosub:1080
r:^jCCS(
1411:
if:1410:$temroom$==$room$
gosub:1210
if:1499:$readf$==
gosub:2510
1499:
ret:
***** Ready to Upload to Library *****
1500:
gosub:1800
if:1599:#fail#==1
if:1501:#libon#==1
nthstr:$temset$:9:$set$
if:1501:$temset$==0
s:LIB^m
set:#libon#:1
r:^j>
1501:
s:LIB $uplib$^m
set:$lib$:$uplib$
r:せん◆^m^j|1510:^jLIB>
fclose:#mesref#
1502:
set:$us$:_?
gosub:2700
gosub:1250
if:1599:$fname$==
if:1502:$uplib$==$lib$
j:1599
1510:
gosub:1900
1599:
ret:
***** Send Message in Patio *****
1600:
if:1699:$fname$==
1601:
gosub:1700
gosub:1230
if:1600:#fail#==1
r:$waitt$|1600:^jPATIO(
gosub:1080
r:^jPATIO(
j:1600
1699:
ret:
***** Comment or Message? *****
1700:
set:#fail#:0
nthstr:$mes$:3:$fname$
if:1702:$mes$==
strwhere:#num#:70[0-9][0-9][0-9]:$mes$
if:1702:#num#==1
s:RE $mes$^m
r:下さい◆^m^j|1701:◆^m^j|1703:行頭で/E)^m^j
j:1710
1701:
nthstr:$temset$:10:$set$
if:1710:$temset$==0
1702:
s:SAY^m
r:^j:|1710:◆^m
s:1^m
r:行頭で/E)^m^j
1703:
fopen:#mesref#:POST:$fname$
gosub:2000
j:1799
1710:
set:#fail#:1
set:$us$:_?
gosub:2700
1799:
ret:
***** Check Upload File *****
1800:
set:#fail#:0
fopen:#mesref#:POST:$fname$
fread:#mesref#:$mesline$
strwhere:#num#:#!FN¥¥::$mesline$
if:1810:#num#<>1
strext:$upfname$:5:99:$mesline$
strwhere:#num#:B¥¥::$upfname$
if:1801:#num#<>1
strext:$upfname$:3:99:$upfname$
ftype:b
1801:
nthstr2:¥r:$upfname$:1:$upfname$
exist:1802:$upfname$
j:1810
1802:
fread:#mesref#:$mesline$
strwhere:#num#:#!TT¥¥:[¥^¥r]:$mesline$
if:1810:#num#<>1
strext:$dataname$:5:99:$mesline$
fread:#mesref#:$mesline$
strwhere:#num#:#!KY¥¥:[¥^¥r,]:$mesline$
if:1899:#num#==1
1810:
fclose:#mesref#
set:#fail#:1
set:$us$:_?
gosub:2700
1899:
ret:
***** Upload to Library *****
1900:
s:UPLoad TYPE:BIN PROT:BPL^m
strext:$mesline$:5:99:$mesline$
nthstr2:¥r:$mesline$:1:$mesline$
r:^j:|1920:^jLIB>
s:$dataname$
set:#keynum#:1
r:^j:
s:1^m
r:^j:
1901:
nthstr2:,:$key$:#keynum#:$mesline$
if:1902:$key$==
s:$key$^m
add:#keynum#:1
r:^j:
s:1^m
r:^j:|1903:行頭で/E)^m
j:1901
1902:
s:^m
r:行頭で/E)^m^j
1903:
gosub:2000
r:^j:
s:1^m
gosub:2100
r:LIB>
1910:
gosub:1250
if:1999:$fname$==
if:1999:$uplib$<>$lib$
gosub:1800
if:1910:#fail#==1
j:1900
1920:
fclose:#mesref#
1921:
set:$us$:_?
gosub:2700
gosub:1250
if:1999:$fname$==
if:1921:$uplib$==$lib$
1999:
ret:
***** Send *****
2000:
fread:#mesref#:$mesline$
if:2001:#err#<>0
if:2001:$mesline$==/POST^m
s:$mesline$
j:2000
2001:
s:/POST*^h^m
fclose:#mesref#
set:$us$:_
gosub:2700
ret:
***** Upload *****
2100:
r:^j:
s:$upfname$^m
r:開始−^m^j
d:2
ulBplus:$upfname$
ftype:m
ret:
***** Search in Library *****
2200:
fread:#searef#:$sealine$
if:2299:#err#<>0
if:2299:$sealine$==/END^m
s:LIB^m
set:#libon#:1
r:^j>
if:2201:$sealine$==^m
s:SEArch $sealine$
j:2202
2201:
s:SEArch^m
2202:
r:^j>
2299:
ret:
***** Download from Library *****
2300:
set:$down$:END
fread:#downref#:$downline$
if:2399:#err#<>0
strmatch:$down$:¥^[0-9]+-[0-9]+:$downline$
if:2399:$down$==
nthstr:$lib$:1:$down$
if:2301:#libon#==1
nthstr:$temset$:9:$set$
if:2301:$temset$==0
s:LIB^m
set:#libon#:1
r:^j>
2301:
s:LIB $lib$^m
r:せん◆^m^j|2310:^jLIB>
2302:
set:$down$:END
fread:#downref#:$downline$
if:2399:#err#<>0
strmatch:$down$:¥^[0-9]+-[0-9]+:$downline$
if:2399:$down$==
nthstr:$temlib$:1:$down$
if:2302:$temlib$==$lib$
j:2301
2310:
nthstr:$down$:2:$down$
s:DOWn PROT:BPL $down$^m
r:^j:|2311:^jLIB>
s:1^m
r:^j:
s:$forum$_$lib$($down$)^m
r:開始−^m^j
d:2
dlBplus:
r:^jLIB>
2311:
set:$down$:END
fread:#downref#:$downline$
if:2320:#err#<>0
strmatch:$down$:¥^[0-9]+-[0-9]+:$downline$
if:2320:$down$==
nthstr:$temlib$:1:$down$
if:2310:$temlib$==$lib$
2320:
gosub:1910
set:$lib$:$temlib$
if:2399:$down$==
if:2301:$down$<>END
2399:
ret:
***** WSEA *****
2400:
set:#order#:0
fread:#wsearef#:$wsea$
if:2499:#err#<>0
if:2499:$wsea$==/END^m
fread:#wsearef#:$wsealine$
if:2499:#err#<>0
if:2499:$wsealine$==/END^m
if:2410:$wsealine$==MLIST^m
s:OPT^m
r:^j>
s:5^m
r:^j:
gosub:1091
strwhere:#order#:ペア:$line$
strwhere:#num#:MREad-RC:$wsealine$
add:#order#:#num#
if:2401:#order#==7
if:2402:#order#==1
s:^m
j:2403
2401:
s:1^m
j:2403
2402:
s:2^m
2403:
r:^j>
2410:
s:MES^m
r:^j>|2499:^jFORUM>
set:#roomon#:1
line:#start#
s:WSEA $wsea$
r:^j>|2411:^jWSEA>
if:2499:$wsealine$==MLIST^m
j:2420
2411:
if:2412:$wsealine$<>MLIST^m
s:MLIST^m
r:^j>
s:E^m
r:^jWSEA>
j:2416
2412:
line:#end#
set:#limit#:999
strmatch:$str$:[0-9]+:$wsealine$
if:2413:$str$==
set:#limit#:$str$
2413:
add:#start#:1
if:2416:#start#==#end#
getline:$line$:#start#
strmatch:$str$:[.0-9]+hit¥¥:[1-9]:$line$
if:2413:$str$==
strext:$str$:1:2:$str$
s:MLIST $str$^m
r:^j>|2413:^jWSEA>
strmatch:$str$:hit¥¥:[0-9]+:$line$
strmatch:$str$:[0-9]+:$str$
set:#num#:$str$
if:2416:#limit#<<#num#
line:#read#
s:ALL^m
2414:
r:^h^m^j>|2415:^j>
j:2416
2415:
nthstr:$temset$:2:$set$
if:2414:$temset$==1
gosub:1090
if:2414:$line$<>>
2416:
s:E^m
r:^j>|2413:^jWSEA>
2420:
if:2421:#order#==1
if:2421:#order#==7
j:2499
2421:
s:OPT^m
r:^j>
s:5^m
r:^j:
if:2422:#order#==1
s:1^m
j:2423
2422:
s:2^m
2423:
r:^j>
2499:
ret:
***** Read Message in Forum *****
2500:
if:2502:#roomon#==0
s:RX $room$^m
r:せん◆^m^j|2510:−^m^jCCS(
2501:
set:$us$:_?
gosub:2720
gosub:1210
if:2501:$readf$<>
j:2599
2502:
nthstr:$temset$:8:$set$
if:2503:$temset$==0
if:2503:#roomon#==1
s:MES^m
r:^j>
2503:
s:MES $room$^m
r:^jCCS(|2501:^j>|2501:^jFORUM>
2504:
set:#roomon#:2
2510:
nthstr:$mes$:3:$readf$
line:#read#
add:#read#:2
s:#!$mes$^m
set:$us$:_
gosub:2720
gosub:1210
2511:
r:^h^m^jCCS(|2512:^jCCS(
j:2520
2512:
line:#num#
if:2513:#num#<>#read#
gosub:2730
j:2520
2513:
nthstr:$temset$:2:$set$
if:2511:$temset$==1
gosub:1090
if:2520:$line$==CCS(N)>
if:2511:$line$<>CCS(P)>
2520:
if:2510:$readf$<>
2599:
ret:
***** Read Title in Forum *****
2600:
nthstr2:/:$temroom$:#num#:$roomline$
if:2699:$temroom$==
2601:
nthstr2:,:$room$:1:$temroom$
if:2602:#roomon#==0
s:RX $room$^m
r:$waitr$|2607::0−^m^jCCS(|2607:せん◆^m^j|2604:−^m^jCCS(
j:2607
2602:
nthstr:$temset$:8:$set$
if:2603:$temset$==0
if:2603:#roomon#==1
s:MES^m
r:^j>
2603:
s:MES $room$^m
set:#roomon#:2
r:^jCCS(|2607:$waitr$|2607::0−^m^jCCS(|2606:せん◆^m
2604:
s:$title$^m
2605:
r:^j>|2607:^jCCS(
s:RC ALL^m
j:2605
2606:
set:#roomon#:0
2607:
strwhere:#num#:,:$temroom$
add:#num#:1
strlen:#length#:$temroom$
strext:$temroom$:#num#:#length#:$temroom$
if:2601:#num#>>1
2699:
ret:
***** Rename File *****
2700:
rename:POST:$fname$:$us$$fname$
if:2709:#err#==0
set:#usnum#:0
2701:
add:#usnum#:1
rename:POST:$fname$:$us$#usnum#_$fname$
if:2701:#err#<>0
2709:
ret:
2710:
set:$us$:_
rename:SCRIPT:$fname$:$us$$fname$
if:2719:#err#==0
set:#usnum#:0
2711:
add:#usnum#:1
rename:SCRIPT:$fname$:$us$#usnum#_$fname$
if:2711:#err#<>0
2719:
ret:
2720:
set:$ranamed$:$us$$readf$
rename:POST:$readf$:$us$$readf$
if:2729:#err#==0
set:#usnum#:0
2721:
add:#usnum#:1
set:$ranamed$:$us$#usnum#_$readf$
rename:POST:$readf$:$us$#usnum#_$readf$
if:2721:#err#<>0
2729:
ret:
2730:
rename:POST:$ranamed$:_?$readf$
if:2739:#err#==0
set:#usnum#:0
2731:
add:#usnum#:1
rename:POST:$ranamed$:_?#usnum#_$readf$
if:2731:#err#<>0
2739:
ret: